How to emulate pushd/popd

[martin-braun]

Before considering z, I always did this:

alias cd='pushd'
alias pd='popd'

The reason is simply, I would keep the navigation history and can call pd multiple times to pop directories off again. I will always be in a branch that I can move up again. Very useful for me.

Now I'm missing something like my pd for z. I'm aware of z -, but calling z - multiple times will alternate back and forth (like the original cd -), because it will put the last directory onto the stack when navigating back. This is not what I want, I want a dir stack by default that I can pop the last directory off using pd.

I also tried z -1, but I get zoxide: no match found. Could somebody please help me out on this one?

[ernieIzde8ski]

Had the same issue, and I came to a solution while messing around with which z for a little while. In case it helps, here's what I did in my dotfiles (uses some possibly zsh-specific syntax):

zsh snippet

if command -v zoxide &>/dev/null; then
    eval "$(zoxide init zsh)"

    # Alias so that I can use `z` in scripts easily, falling back to `cd`.
    #
    # It would be valid to override the builtins: `alias cd=z`
    # since internally, `__zoxide_cd` is defined as `\builtin cd -- "$@"`,
    # but that's just not something I want to do.
    alias zcd=z

    function __dotfiles_pushz_emit_help() {
        echo -n "usage: $1" 1>&2
        echo -n ' [<pushd-flag | "-h" | "--help" | "--debug">...]' 1>&2
        echo ' [--] [<z-argument>...]\n' 1>&2

        echo 'options:'
        echo "\t pushd-flag"
        echo "\t\t Adds a flag to send to pushd. Must begin with a hyphen."
        echo "\t z-argument"
        echo "\t\t Adds an argument to send to z."
        echo "\t -h, --help"
        echo "\t\t Displays this message."
        echo "\t --debug"
        echo "\t\t Halts evaluation of pushz after option interpretation."
        echo "\t\t Displays arguments that would be used."
    }

    # push directory
    function pushz() {
        local origin="$PWD"
        local target=""
        local pushd_flags=()
        local z_arguments=()

        local debug=false
        local evaluate_flags=true

        for argument in "$@"; do
            if [[ "$evaluate_flags" == false ]]; then
                z_arguments+=("$argument")
            elif [[ "$argument" == "--" ]]; then
                evaluate_flags=false
            elif [[ "$argument" == "-h" || "$argument" == "--help" ]]; then
                __dotfiles_pushz_emit_help "$0"
                return 0
            elif [[ "$argument" == '--debug' ]]; then
                debug=true
            elif [[ "$argument" =~ '[-\+][0123456789]+' ]]; then
                echo 'the `-+{N}` operator is not supported' 1>&2
                return 1
            elif [[ "$argument" == '-'* ]]; then
                pushd_flags+=("$argument")
            else
                z_arguments+=("$argument")
                evaluate_flags=false
            fi
        done

        if [[ $debug == true ]]; then
            echo "origin=${origin}"
            echo "pushd_flags=$(printf '%q ' "${pushd_flags[@]}")"
            echo "z_arguments=$(printf '%q ' "${z_arguments[@]}")"
            return 0
        fi

        z "$z_arguments[@]" && {
            target="$PWD"
            \builtin cd "$origin"
            \builtin pushd "$pushd_flags[@]" "$target"
        }
    }
    # pop directory, complimenting pushz
    alias popz='popd'
else
    alias zcd=cd
    alias pushz=pushd
    alias popz=popd
fi

Advantages of this function:

• \builtin pushd is used, so most pushd options are valid to pushz regardless of shell version
  • \builtin cd "$origin" is fallen back to, so if your pushd options are invalid, it's still okay.
  • Some argument parsing handles argument splitting, so keeping your pushd and zoxide arguments separate should be easy.
• No __zoxide_* internal is used, so this should continue to work if zoxide is updated.

Disadvantages:

• Haven't checked, but can almost guarantee that I used zsh-exclusive syntax. Might require some revisions to work better with bash, etc.
• Shell argument parsing is a nightmare.
  • Only -short and --long options can be passed into the pushd invocation.
    • pushz can only be used to invoke the form pushd [ "-" + opts ] [ ARG ].
    • pushz cannot be used to invoke the form pushd [ "-" + opts ] OLD NEW.
    • pushz cannot be used to invoke the form pushd [ "-" + opts ] {+|-}N.

Examples of pushz and popz in action

[1] ernie@vivec::~% which zc; which zp
zc: aliased to pushz
zp: aliased to popz

# pushz updates the ${dirstack} using pushd.
[1] ernie@vivec::~% zc indarys
/mnt/indarys ~
[1] ernie@vivec::indarys% zc indarys projects
/mnt/indarys/projects /mnt/indarys ~
# popz is popd.
[1] ernie@vivec::projects% zp
/mnt/indarys ~
[1] ernie@vivec::indarys%

# Invalid invocations of pushd don't move you or update ${dirstack}.
[1] ernie@vivec::indarys% zc foobarbaz
zoxide: no match found
Process exited with code 1
[1] ernie@vivec::indarys% dirs
/mnt/indarys ~

# Options starting with a hyphen can be passed to builtin pushd, if they are the first arguments.
[1] ernie@vivec::indarys% zc -q Doc
[1] ernie@vivec::Documents%

# And arguments starting with a hyphen can be explicitly passed to zoxide,
# when either a command with two hyphens precedes it, or another zoxide-argument precedes it.
[1] ernie@vivec::Documents% zc -- -packages; zp; zc home -packages
~/void-packages ~/Documents /mnt/indarys ~
~/Documents /mnt/indarys ~
~/void-packages ~/Documents /mnt/indarys ~
[1] ernie@vivec::void-packages%