forked from emacs-jupyter/jupyter
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathjupyter-kernelspec.el
175 lines (141 loc) · 6.86 KB
/
jupyter-kernelspec.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
;;; jupyter-kernelspec.el --- Jupyter kernelspecs -*- lexical-binding: t -*-
;; Copyright (C) 2018-2020 Nathaniel Nicandro
;; Author: Nathaniel Nicandro <[email protected]>
;; Created: 17 Jan 2018
;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License as
;; published by the Free Software Foundation; either version 3, or (at
;; your option) any later version.
;; This program is distributed in the hope that it will be useful, but
;; WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
;; General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING. If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.
;;; Commentary:
;; Functions to work with kernelspecs found by the shell command
;;
;; jupyter kernelspec list
;;; Code:
(require 'json)
(require 'jupyter-env)
(defgroup jupyter-kernelspec nil
"Jupyter kernelspecs"
:group 'jupyter)
(declare-function jupyter-read-plist "jupyter-base" (file))
(declare-function jupyter-read-plist-from-string "jupyter-base" (file))
(defvar jupyter--kernelspecs (make-hash-table :test #'equal :size 5)
"An alist matching kernel names to their kernelspec directories.")
(defun jupyter-read-kernelspec (dir)
"Return the kernelspec found in DIR.
If DIR contains a \"kernel.json\" file, assume that it is the
kernelspec of a kernel and return the plist created by a call to
`jupyter-read-plist'."
(let ((file (expand-file-name "kernel.json" dir)))
(if (file-exists-p file) (jupyter-read-plist file)
(error "No kernel.json file found in %s" dir))))
(defun jupyter-available-kernelspecs (&optional refresh)
"Get the available kernelspecs.
Return an alist mapping kernel names to (DIRECTORY . PLIST) pairs
where DIRECTORY is the resource directory of the kernel and PLIST
is its kernelspec plist. The alist is formed by parsing the
output of the shell command
jupyter kernelspec list
By default the available kernelspecs are cached. To force an
update of the cached kernelspecs, give a non-nil value to
REFRESH.
If the `default-directory' is a remote directory, return the
mapping for the kernelspecs on the remote host. In this case,
each DIRECTORY will be a remote file name."
(let ((host (or (file-remote-p default-directory) "local")))
(or (and (not refresh) (gethash host jupyter--kernelspecs))
(let ((specs (plist-get
(jupyter-read-plist-from-string
(or (jupyter-command "kernelspec" "list" "--json")
(error "Can't obtain kernelspecs from jupyter shell command")))
:kernelspecs)))
(puthash
host (cl-loop
for (name spec) on specs by #'cddr
for dir = (concat (unless (equal host "local") host)
(plist-get spec :resource_dir))
collect (cons (substring (symbol-name name) 1)
(cons dir (plist-get spec :spec))))
jupyter--kernelspecs)))))
(defun jupyter-get-kernelspec (name &optional refresh)
"Get the kernelspec for a kernel named NAME.
If no kernelspec is found, return nil. Otherwise return the
kernelspec plist for the kernel names NAME. Optional argument
REFRESH has the same meaning as in
`jupyter-available-kernelspecs'."
(cdr (assoc name (jupyter-available-kernelspecs refresh))))
(defun jupyter-find-kernelspecs (re &optional specs refresh)
"Find all specs of kernels that have names matching matching RE.
RE is a regular expression use to match the name of a kernel.
Return an alist with elements of the form:
(KERNEL-NAME . (DIRECTORY . PLIST))
where KERNEL-NAME is the name of a kernel that matches RE,
DIRECTORY is the kernel's resource directory, and PLIST is the
kernelspec propery list read from the \"kernel.json\" file in the
resource directory.
If SPECS is non-nil search SPECS, otherwise search the specs
returned by `jupyter-available-kernelspecs'.
Optional argument REFRESH has the same meaning as in
`jupyter-available-kernelspecs'."
(cl-remove-if-not
(lambda (s) (string-match-p re (car s)))
(or specs (jupyter-available-kernelspecs refresh))))
(defun jupyter-guess-kernelspec (name &optional specs refresh)
"Return the first kernelspec matching NAME.
Raise an error if no kernelspec could be found.
SPECS and REFRESH have the same meaning as in
`jupyter-find-kernelspecs'."
(or (car (jupyter-find-kernelspecs name specs refresh))
(error "No valid kernelspec for kernel name (%s)" name)))
(defun jupyter-completing-read-kernelspec (&optional specs refresh)
"Use `completing-read' to select a kernel and return its kernelspec.
The returned kernelspec has the form
(KERNEL-NAME . (DIRECTORY . PLIST))
where KERNEL-NAME is the name of the kernel, DIRECTORY is the
resource directory of the kernel, and PLIST is the kernelspec
plist.
If SPECS is non-nil then it should be a list of kernelspecs that
will be used to select from otherwise the list of kernelspecs
will be taken from `jupyter-available-kernelspecs'.
Optional argument REFRESH has the same meaning as in
`jupyter-available-kernelspecs'."
(let* ((specs (or specs (jupyter-available-kernelspecs refresh)))
(display-names (if (null specs) (error "No kernelspecs available")
(mapcar (lambda (k) (plist-get (cddr k) :display_name))
specs)))
(name (completing-read "kernel: " display-names nil t)))
(when (equal name "")
(error "No kernelspec selected"))
(nth (- (length display-names)
(length (member name display-names)))
specs)))
;; TODO: Define a kernel-spec mode alist mapping languages
;; to the modes that they may use.
(defun jupyter-kernelspecs-for-mode (&optional mode refresh)
"Attempt to find available kernelspecs for MODE.
MODE should be a major mode symbol and defaults to `major-mode'.
REFRESH has the same meaning as in
`jupyter-available-kernelspecs'. Return a list of available
kernelspecs or nil if none could be found. Note that this does
not mean that no kernel exists for MODE.
Currently this just concatenates the kernelspec language name
with `-mode' to see if `major-mode' is equivalent. This is
sufficient for `python' and `julia' kernels using their standard
major modes, but most likely will fail for other cases."
(cl-loop
for kernelspec in (jupyter-available-kernelspecs refresh)
for (_kernel . (_dir . spec)) = kernelspec
for language = (plist-get spec :language)
;; attempt to match the major mode to a spec
if (eq (intern (concat language "-mode"))
(or mode major-mode))
collect kernelspec))
(provide 'jupyter-kernelspec)
;;; jupyter-kernelspec.el ends here